Mengatur Tab dalam Visual Basic 6.0

Kemarin saya dapat pertanyaan di halaman ini, tentang tab di visual basic 6.0. Pertanyaannya adalah sebagai berikut:

"gmn cara setting tab biar saat login , yg kebuka tab paling kiri….n` gmn buat tombol agar bsa pindah tab…tq b4 atas bantuannya….."

Saya coba tangkap pertanyaannya seperti ini,

1. Bagaimana caranya saat kita login, login berada di tab, di mana posisi loginnya di tab yang paling kiri.


2. Tombol bisa buat pindah tab bisa berarti assign key ke key board untuk bisa pindah tab atau Command Button yang bisa pindah tab, saya buat dua-duanya

Ok langkah pertama adalah membuat File Baru. Setelah itu, masuk ke Project-> Components... atau tekan Crtl + T. Dari situ, centang Microsoft Tabbed Dialog Control 6.0, Jika Anda tidak bisa menemukannya, coba Anda browse dan cari file dengan nama TABCTL32.OCX. Untuk jelasnya, coba lihat gambar di bawah:

Gambar Project -> Components...

Setelah itu, klik ok. Maka kini di Toolbox Anda akan muncul satu Control tambahan, yaitu Control SSTAB. Lihat gambar di bawah untuk lebih jelasnya.

Gambar Toolbox dengan SSTAB

Setelah itu, pastikan property form Anda untuk property Key Preview = true, property ini di gunakan agar form selalu mengetahui key yang anda tekan. Hal ini nantinya kita manfaatkan untuk membuat key pindah tab dengan tombol key board.

Setelah itu, letakan tab SSTAB di Form Anda.

Rancanglah Tab 1 Seperti di bawah ini.

Gambar Tab1

Rancanglah Tab 2 Seperti di bawah ini.

Gambar Tab 2

Rancanglah Tab 3 Seperti di bawah ini.

Gambar Tab 3

Untuk lebih jelasnya berikut ini adalah ditail propertynya dari Form1:

VERSION 5.00
Object = "{BDC217C8-ED16-11CD-956C-0000C04E4C0A}#1.1#0"; "TABCTL32.OCX"
Begin VB.Form Form1
   Caption         =   "Form1"
   ClientHeight    =   4800
   ClientLeft      =   60
   ClientTop       =   345
   ClientWidth     =   6405
   KeyPreview      =   -1  'True
   LinkTopic       =   "Form1"
   ScaleHeight     =   4800
   ScaleWidth      =   6405
   StartUpPosition =   3  'Windows Default
   Begin TabDlg.SSTab stab
      Height          =   4455
      Left            =   120
      TabIndex        =   0
      Top             =   120
      Width           =   6015
      _ExtentX        =   10610
      _ExtentY        =   7858
      _Version        =   393216
      Tab             =   1
      TabHeight       =   520
      TabCaption(0)   =   "Tab 0"
      TabPicture(0)   =   "Form1.frx":0000
      Tab(0).ControlEnabled=   0   'False
      Tab(0).Control(0)=   "txtPass"
      Tab(0).Control(1)=   "cmdLogin"
      Tab(0).Control(2)=   "Label1"
      Tab(0).ControlCount=   3
      TabCaption(1)   =   "Tab 1"
      TabPicture(1)   =   "Form1.frx":001C
      Tab(1).ControlEnabled=   -1  'True
      Tab(1).Control(0)=   "Label2"
      Tab(1).Control(0).Enabled=   0   'False
      Tab(1).Control(1)=   "cmdPindah"
      Tab(1).Control(1).Enabled=   0   'False
      Tab(1).ControlCount=   2
      TabCaption(2)   =   "Tab 2"
      TabPicture(2)   =   "Form1.frx":0038
      Tab(2).ControlEnabled=   0   'False
      Tab(2).Control(0)=   "cmdLogout"
      Tab(2).ControlCount=   1
      Begin VB.CommandButton cmdPindah
         Caption         =   "cmdPindah"
         Height          =   375
         Left            =   2160
         TabIndex        =   6
         Top             =   2400
         Width           =   1575
      End
      Begin VB.CommandButton cmdLogout
         Caption         =   "Log Out"
         Height          =   495
         Left            =   -73200
         TabIndex        =   5
         Top             =   1920
         Width           =   2175
      End
      Begin VB.TextBox txtPass
         Height          =   375
         IMEMode         =   3  'DISABLE
         Left            =   1080
         PasswordChar    =   "*"
         TabIndex        =   2
         Top             =   1680
         Width           =   3975
      End
      Begin VB.CommandButton cmdLogin
         Caption         =   "Login"
         Height          =   495
         Left            =   -72960
         TabIndex        =   1
         Top             =   2520
         Width           =   1935
      End
      Begin VB.Label Label2
         Alignment       =   2  'Center
         Caption         =   "Ini Tab Tengah"
         Height          =   495
         Left            =   600
         TabIndex        =   4
         Top             =   2040
         Width           =   4695
      End
      Begin VB.Label Label1
         Alignment       =   2  'Center
         BorderStyle     =   1  'Fixed Single
         Caption         =   "Enter Yous Password"
         Height          =   255
         Left            =   -73440
         TabIndex        =   3
         Top             =   1200
         Width           =   3135
      End
   End
End
Attribute VB_Name = "Form1"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False

Berikut ini adalah script Visual Basic 6.0 ( VB 6.0 ) nya lengkap dengan keterangan

'Langkah Pertama, deklarasi Variabel

'Var Untuk cek user lagi login atau tidak
Dim log_in As Boolean

'Var untuk cek posisi Button ada di tab mana
Dim posisiButton As Integer

'Fungsi untuk ganti tab
Sub changeTab(index As Integer)
    'Jika user aktif dan tab tujuan bukan layar login
    'atau
    'Jika user tidak aktif dan tab tujuan adalah layar login
    'maka bisa ganti tab
    If log_in And Not index = 0 Or Not log_in And index = 0 Then stab.Tab = index
End Sub

'Fungsi Buat Matiin semua tab agar tidak bisa di akses
Sub disabledAllTab()
    Dim i As Integer
    For i = 1 To 2
        stab.TabEnabled(i) = False
    Next i
End Sub

'Fungsi Log Out
Sub logout()
    'buat stat user tidak login
    log_in = False

    'matikan semua tab
    disabledAllTab

    'buat hanya tab login yang bisa di akses
    stab.TabEnabled(0) = True

    'Pindahkan tab ke layar login
    changeTab 0
End Sub

'Eksesuki Pertama, Form Load
Private Sub Form_Load()
    'reset semua stat
    logout

    'Posisi awal button yang bisa pindah tab
    posisiButton = 1
End Sub

'Fungsi Login
Function login(pass As String) As Boolean
    'Nanti silakan di edit, agar langsung akses ke db
    If pass = "PASS" Then login = True Else login = False
End Function

'Fungsi tombol login di tekan
Private Sub cmdLogin_Click()
    'apakah pass benar?
    If login(Me.txtPass.Text) Then
        'Jika Benar maka tab login mati
        'Tab tengah dan kanan bisa di akses
        For i = 1 To 2
            stab.TabEnabled(i) = True
        Next i
        stab.TabEnabled(0) = False

        MsgBox "Login Berhasil", vbInformation

        'Status user telah login
        log_in = True

        'Pindahkan ke tab tengah
        changeTab 1
    Else
        'Passport salah
        MsgBox "Wrong Password", vbExclamation
    End If

    'reset passport
    Me.txtPass.Text = ""
End Sub

'Fungsi Log Out
Private Sub cmdLogout_Click()
    MsgBox "Loging Out", vbInformation
    logout
End Sub

'Tombol Key Board untuk Pindah Tab
Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
    'asc untuk mengubah Key Asli jadi keycode

    'tekan 1 maka akan ke tab kiri
    If KeyCode = Asc(1) Then
        changeTab 0

    'tekan 2 maka akan ke tab tengah
    ElseIf KeyCode = Asc(2) Then
        changeTab 1

    'tekan 3 maka akan ke tab paling kanan
    ElseIf KeyCode = Asc(3) Then
        changeTab 2
    End If
End Sub

'Fungsi memindahkan tombol dari
'satu tab ke tab lainnya
Private Sub cmdPindah_Click()

    'Pindahkan Button ke Form
    Set cmdPindah.Container = Form1

    'Jika button di tab 1
    If posisiButton = 1 Then
        'ke tab 2
        stab.Tab = 2
        'ubah var posisi tab di 2
        posisiButton = 2
    Else
        ' ke tab 1
        stab.Tab = 1
        'ubah var posisi tab di 1
        posisiButton = 1
    End If
    'pindahkan button ke tab terpilih
    Set cmdPindah.Container = stab
End Sub

Ok itu saja, jika ingin filenya, filenya bisa di download di sini.

Ok semoga bermanfaat.